Calculation of LLs for ππ scattering in O(N+1) σ-model.
See details in hep-ph/0809.3236

Definitions

Deffinition of Ω (Eq. (15))- the function Om[n,A,B] & β-function coefficients Eq. (14) -function bN

Om[n_, A_, 
        B_] := Om[n, A, 
          B] = (2  B + 
              1) (((-1))^(n + 
                B)) ((n! n!)/((n - B)! (n + B + 
                      1)!)) 
          HypergeometricPFQ[{-A, A + 1, -1 - n - B, 
              B - n}, {1, -n, -n}, 1]

bN[i_, A_, j_, B_, r_] := bN[i, A, j, B, r] = 
        If[EvenQ[r] && EvenQ[A] && 
            EvenQ[B], (N/2) ((KroneckerDelta[A, B] KroneckerDelta[A, r])/(2  A + 1)) +  Om[j, B, A] KroneckerDelta[A, r]/(2  A + 1) + 
            Om[i, A, B] KroneckerDelta[B, r]/(2  B + 1) + 
            2  Sum[((Om[i, A, J] Om[j, B, J] Om[i + j, J, r])/(2  J + 1)), {J, 0, Min[i, j]}], 0]

Deffinition of (Subscript[ω, nC])-functions & (Subscript[A, n]) and (Subscript[B, n])-- coefficients

Here
	ω[n,j] -- gives (Subscript[ω, nj   ]) 
        defined in Eq .  (12)
	A[n] and B[n]  -- gives LLs defined in Eq. (4)

ωN[1, 0] := 1
ωN[1, a_] := 0
ωN[n_, 
        C_] := ωN[n, C] = (1/(n - 1)) 
          Sum[Sum[Sum[
                bN[i, A, n - i, B, C] ωN[i, A] ωN[n - i, 
                    B], {A, 0, i, 2}], {B, 0, n - i, 2}], {i, 1, 
              n - 1}]

ω[n_, C_] := ωN[n + 1, C]

a[n_] := 
      If[OddQ[n], Sum[ωN[n, A], {A, 0, n + 1, 2}], 
        If[EvenQ[n],  Sum[ωN[n, A], {A, 0, n + 1, 2}], 0]]

b[n_] := 
      If[EvenQ[n],  (((2  
                    n)!)/((n)! (n)!)) ωN[n, n], 
        0]

A[n_] := a[n + 1]; B[n_] := b[n + 1];

Example A[7] and B[9]

Collect[A[7], N]

Collect[B[9], N]